#!/usr/local/bin/perl

#=============================================================================#
#									      #
#  This CGI script submits calendar items.				      #
#									      #
#=============================================================================#
#  Author:  Don Thomson							      #
#=============================================================================#

use strict;

use CGI;
use CGI::Carp qw(fatalsToBrowser confess);

my($Mail_To, $Title, %Fields);


#=============================================================================#
#  Main body								      #
#=============================================================================#

initialize();

my $q = new CGI;

print $q->header;

print $q->start_html(-title=>$Title,
		     -bgcolor=>'#FFFFCC',
		     -link=>'#008000',
		     -vlink=>'#800080'), "\n";

display_file('header.html');

if ($q->param('submit')) 
    {
    submit_form();
    } 
else 
    {
    display_form();
    }

display_file('footer.shtml', '<!--#');

print $q->end_html;

exit;


#=============================================================================#
#  Perform initializations						      #
#=============================================================================#

sub initialize
    {
    my $local_host;

    chop($local_host = `hostname`);
    $local_host =~ s/\..*//;

    $Mail_To = 
	$local_host eq 'zack' 	# Test host
	    ? 'dthomson@fammed.wisc.edu'
	    : 'webmaster@dmna.org';
    
    $Title = 'Submit a Calendar Event';

    %Fields =
	(
	#    label      Label as it will appear on request form
        #    prompt     Longer prompt to be used in place of above on request
	#               form, but not on confirmation or emailed request
        #    composite  Field contains subfields (i.e. date pulldown menus)
	#    required   Set to 1 if field is required (or if it has 'select')
	#    str_sub    Subroutine that returns formatted field string
        #    newline    Print newline before contents when sending request
	#    order      Order in which field will appear on request form

	submitter_name => 
	     {
	     prompt   => 'Your Name',
	     label    => 'Submitter Name',
	     required => 1,
	     order    => 1,
	     },

	submitter_email => 
	     {
	     prompt   => 'Your Email Address',
	     label    => 'Submitter Email',
	     required => 0,
	     order    => 2,
	     },

	submitter_phone => 
	     {
	     prompt   => 'Your Phone Number',
	     label    => 'Submitter Phone Number',
	     required => 1,
	     order    => 3,
	     },

	event_name => 
	     {
	     label    => 'Event Name',
	     required => 1,
	     order    => 4,
	     },

	date => 
	     {
	     label     => 'Date', 
	     required  => 1,
	     composite => 1,
	     str_sub   => \&date_param,
	     order     => 5,
	     }, 

	time => 
	     {
	     label    => 'Time',
	     required => 1,
	     order    => 6,
	     },

	location => 
	     {
	     label    => 'Location',
	     required => 1,
	     order    => 7,
	     },

	desc => 
	     {
	     label    => 'Description',
	     order    => 8,
	     newline  => 1,
	     },

	comment => 
	     {
	     label    => 'Comments',
	     order    => 9,
	     newline  => 1,
	     },
	 );
    }


#=============================================================================#
#  Open and display specifed file					      #
#=============================================================================#

sub display_file
    {
    my($file_name, $skip) = @_;

    $file_name = join('/', $ENV{DOCUMENT_ROOT}, $file_name);

    open(FILE,$file_name) || die "*** Unable to open file '$file_name' ***\n";

    my $line;

    while (defined($line = <FILE>)) 
	{
	next if $skip && $line =~ /$skip/;

	print $line;
	}

    close(FILE);
    }


#=============================================================================#
#  Display calendar event submission form				      #
#=============================================================================#

sub display_form
    {
    my $col_width = 50;

    my $submit_buttons = 
	$q->center($q->submit(-name=>'submit',
			      -value=>'Submit Event') . "\n" . 
		   $q->reset(-value=>'Reset Form') . "\n") . "\n";
	
    print $q->center($q->h2($Title)), "\n",

          $q->startform, "\n",
          
          $submit_buttons, 

          '(', $q->strong('*'), ') Required Field', "\n",

          $q->p, "\n",

          $q->table("\n",
		    $q->TR("\n",
			   label('submitter_name'),

			   $q->td($q->textfield(-name=>'submitter_name',
						-size=>$col_width)), "\n",
			   ), "\n",

		    $q->TR("\n",
			   label('submitter_email'),

			   $q->td($q->textfield(-name=>'submitter_email',
						-size=>$col_width)), "\n",
			   ), "\n",

		    $q->TR("\n",
			   label('submitter_phone'),

			   $q->td($q->textfield(-name=>'submitter_phone',
						-size=>$col_width)), "\n",

			   ), "\n",

		    $q->TR("\n",
			   label('event_name'),

			   $q->td($q->textfield(-name=>'event_name',
						-rows=>2,
						-size=>$col_width)), "\n",
			   ), "\n",

		    $q->TR("\n",
			   label('date'),

			   $q->td(date_popup_menu('date')), "\n",
			   ), "\n",

		    $q->TR("\n",
			   label('time'),

			   $q->td($q->textfield(-name=>'time',
						-size=>$col_width)), "\n",
			   ), "\n",

		    $q->TR("\n",
			   label('location'),

			   $q->td($q->textarea(-name=>'location',
					       -rows=>2,
					       -columns=>$col_width,
					       -wrap=>'physical')), "\n",
			   ), "\n",

		    $q->TR("\n",
			   label('desc'),

			   $q->td($q->textarea(-name=>'desc',
					       -rows=>4,
					       -columns=>$col_width,
					       -wrap=>'physical')), "\n",
			   ), "\n",


		    $q->TR("\n",
			   label('comment'),

			   $q->td($q->textarea(-name=>'desc',
					       -rows=>4,
					       -columns=>$col_width,
					       -wrap=>'physical')), "\n",
			   ), "\n",

		    ), "\n",

          $submit_buttons,
	
          $q->endform;
    }


#=============================================================================#
#  Construct HTML label for a field					      #
#=============================================================================#

sub label
    {
    my($field) = @_;

    my $str = prompt_str($field);

    $str .= ':' if $str !~ /\?$/;

    $str .= ' ';

    return $q->td($Fields{$field}{required} ? $q->strong('*') : ' ') . "\n" .

	   $q->td($q->strong($str)) . "\n";
    }


#=============================================================================#
#  Return the prompt string for a given field				      #
#=============================================================================#

sub prompt_str
    {
    my($field) = @_;

    my $str = $Fields{$field}{prompt};

    $str = $Fields{$field}{label} if ! $str;

    return $str;
    }


#=============================================================================#
#  Submit calendar event submission form			              #
#=============================================================================#

sub submit_form
    {
    my @missing_fields = check_required_fields();

    if (@missing_fields)
	{
	print $q->br, "\n",

	      $q->h3('Your calendar event submission is missing the ' . 
		     'following required fields:'), "\n", $q->p, "\n",

              "<UL>\n";

	foreach my $field (@missing_fields)
	    { 
	    print $q->strong(prompt_str($field)), "\n", $q->p, "\n";
	    }

	print "</UL>\n",

	      $q->h3("Please use your browser's BACK button to go back " . 
		     "and fill in the required fields."),

              "\n";
	} 
    
    else 
	{
	send_mail();

	print $q->center($q->h3('Your calendar event has been submitted.'), 
                         "\n",

			 $q->h3('It will be reviewed by the Webmaster and' . 
				' then added to the calendar.'), "\n",

			 $q->h3($q->i('Thank you!')), "\n",

			 ), "\n",

	      $q->p, "\n";
	}
    }


#=============================================================================#
#  Check query for inclusion of all required fields	      		      #
#=============================================================================#

sub check_required_fields
    {
    my($empty_value, $value, @missing_fields);

    foreach my $field 
	(sort { $Fields{$a}{order} <=> $Fields{$b}{order} } keys %Fields)
        {
	if ($Fields{$field}{composite})
	    {
	    $empty_value = 0;
	    }

	else
	    {
	    $value = trim_whitespace($q->param($field));

	    $empty_value = $value eq '';
	    }

	if ($Fields{$field}{required} && $empty_value)
	    { 
	    push(@missing_fields, $field);
	    }
	}

    return @missing_fields;
    }


#=============================================================================#
#  Send calendar event submission					      #
#=============================================================================#

sub send_mail 
    {
    my($label, $newline, $sub, $value);

    my $submitter_name = trim_whitespace($q->param('submitter_name'));

    my $submitter_email = trim_whitespace($q->param('submitter_email'));

    my $sendmail = '/usr/lib/sendmail -t';

    open(MAIL, "| $sendmail") || die "Can't fork $sendmail: $!\n";

    print MAIL "To: $Mail_To\n",
               "Subject: Calendar Event Submission\n\n",

               "CALENDAR EVENT SUBMISSION\n\n",
               '    (Submitted: ', date_time(time), ' from: "', 
               $q->remote_host, '")', "\n";

    foreach my $field 
	(sort { $Fields{$a}{order} <=> $Fields{$b}{order} } keys %Fields)
        {
	$label = $Fields{$field}{label};

	$label = uc $label;

	if ($sub = $Fields{$field}{str_sub})  # Call sub to construct string
	    { 
	    $value = &$sub(0);
	    }

	else
	    { 
	    $value = trim_whitespace($q->param($field));
	    }

	$newline = $Fields{$field}{newline};

	$label .= ': ';
	$label .= "\n\n" if $newline;

	if ($value)
	    { 
	    print MAIL "\n", $label, $value;

	    print MAIL "\n" if $value !~ /\n$/;
	    }
	}


    close(MAIL);
    }


#=============================================================================#
#  Trim leading and trailing whitespace from string			      #
#=============================================================================#

sub trim_whitespace
    {
    my($str) = @_;
    
    $str =~ s/^\s+|\s+$//g;

    return $str;
    }


#=============================================================================#
#  Create formatted date/time string from time value                          #
#=============================================================================#

sub date_time
    {
    my($time) = @_;

    my @MONTHS = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
    my @DAYS   = qw(Sun Mon Tue Wed Thu Fri Sat);

    my($sec, $min, $hour, $mday, $mon, $year, $wday) = localtime($time);

    return sprintf("%s-%02d-%d (%s) %02d:%02d", $MONTHS[$mon], $mday, 
		   $year + 1900, $DAYS[$wday], $hour, $min);
    }


#=============================================================================#
#  Build a set of month/date selection popup menus			      #
#=============================================================================#

sub date_popup_menu
    {
    my($param_name) = @_;

    my %month_names = 
	(
	1  => 'January',
	2  => 'February',
	3  => 'March',
	4  => 'April',
	5  => 'May',
	6  => 'June',
	7  => 'July',
	8  => 'August',
	9  => 'September',
	10 => 'October',
	11 => 'November',
	12 => 'December',
	);

    my($current_day, $current_month, $current_year) = (localtime)[3, 4, 5];
    $current_year += 1900;
    $current_month += 1;

    my $month_button = 
	$q->popup_menu(-name=>join('_', $param_name, 'month'),
		       -values=>[1..12],
		       -labels=>\%month_names,
		       -default=>$current_month);
    my $day_button = 
	$q->popup_menu(-name=>join('_', $param_name, 'day'),
		       -values=>[1..31],
		       -default=>$current_day);
    my $year_button = 
	$q->popup_menu(-name=>join('_', $param_name, 'year'),
		       -values=>[$current_year .. $current_year + 1],
		       -default=>$current_year);

    return $month_button . $day_button . $year_button;
    }


#=============================================================================#
#  Convert args from pop-up dates to DD-MON-YY format 			      #
#=============================================================================#

sub date_param
    {
    my $param_name = 'date';

    return sprintf "%02d/%d/%d", 
                   $q->param(join('_', $param_name, 'month')),
                   $q->param(join('_', $param_name, 'day')),
                   $q->param(join('_', $param_name, 'year'));
    }